ＳＲＣ質問掲示板Mk2 [One Topic All View / Re[5]: 全体状態変化 / Page: 0]

ＳＲＣ質問掲示板Mk2
(現在過去ログ86 を表示中)

[ 最新記事及び返信フォームをトピックトップへ ]

■15801 / inTopicNo.1)

　全体状態変化

□投稿者/ もけ -(2005/01/07(Fri) 21:43:30) [ID:emsUwaTD]

どうも、もけです
ユニットコマンドで味方全体に影響を与えるものを作ろうと思い、
指揮というコマンドを作ったのですがうまくいきません。
選んだ選択肢にあわせて味方の能力を変化させたいのですが・・・。
味方ユニットにはID味方を、敵ユニットにはID敵を指定した上で試したのですが
うまく動きません。
一応自分が作ったものをのせたので、うまい作り方がわかる人がいたら、
指導していただきたいです。

ユニットコマンド指揮隊長:
Ask 選択してくださいキャンセル可
突撃
防御
かく乱
End

Switch 選択
Case 1
Talk 隊長
よし、総員突撃！
End
GoTo 通常突撃
Case 2
Talk 隊長
防御陣形を取れ！
End
GoTo 通常防御
Case 3
Talk 隊長
総員散れっ！敵をかく乱する！
End
GoTo 通常かく乱
EndSw
Exit

突撃:
SetStatus 味方攻撃力ＵＰ 1
SetStatus 味方移動力ＵＰ 1
SetStatus 味方防御力ＤＯＷＮ 1
exit

防御:
SetStatus 味方防御力ＵＰ 1
SetStatus 味方運動性ＤＯＷＮ 1
SetStatus 味方攻撃力ＤＯＷＮ 1
exit

かく乱:
SetStatus 味方運動性ＵＰ 1
SetStatus 味方攻撃力ＤＯＷＮ
SetStatus 味方防御力ＤＯＷＮ 1
SetStatus 敵撹乱 1
exit

引用返信/返信削除キー/

■15802 / inTopicNo.2)

　Re[1]: 全体状態変化

▲▼■

□投稿者/ TomTom -(2005/01/07(Fri) 21:51:28) [ID:mc0S8D3Q]

TomTomです。

＞SetStatus 味方攻撃力ＵＰ 1

SetStatusで陣営を使用することは不可能です。
ForEach～Nextコマンドを使用して味方一体一体にSetStatusを実行してください。

引用返信/返信削除キー/

■15803 / inTopicNo.3)

　Re[1]: 全体状態変化

▲▼■

□投稿者/ もけ -(2005/01/07(Fri) 22:45:34) [ID:emsUwaTD]

TomTomさんありがとうございます。
試したところきちんと動きました。が、
なぜか指揮コマンドが2個出てしまいます。バグでしょうか？

引用返信/返信削除キー/

■15804 / inTopicNo.4)

　Re[2]: 全体状態変化

▲▼■

□投稿者/ TomTom -(2005/01/07(Fri) 22:58:53) [ID:mc0S8D3Q]

TomTomです。

シナリオ側のバグでしょう。
どこかに余計なユニットコマンドイベントが無いか確認してください。

もしくはGotoコマンドで移動をしているのが不具合の元になっているのかもしれません。
　GoTo 通常突撃　＞ Call 通常突撃
　通常攻撃:～Exit　＞通常攻撃:～Return
に書き換えてみてください。

引用返信/返信削除キー/

■15806 / inTopicNo.5)

　Re[3]: 全体状態変化

▲▼■

□投稿者/ もけ -(2005/01/08(Sat) 00:22:15) [ID:emsUwaTD]

変更してみたけどだめでした。
コマンドのテストのために使っているシナリオの内容はこんな感じです。
@オリジナル

スタート:

Center 10 17
Create 味方隊長 0 隊長 20 6 18
Create 味方部下 0 部下1 20 15 17
Create 味方部下 0 部下2 20 15 18

Create 敵魔獣 0 魔獣(ザコ) 20 9 4
Create 敵魔獣 0 魔獣(ザコ) 20 8 6
Create 敵魔獣 0 魔獣(ザコ) 20 7 6

Exit

ターン全味方:
Set 指揮判定 0
Exit

ユニットコマンド指揮隊長:
If 指揮判定 = 0 Then
Call 指揮
Else
Call 指揮不可
EndIf
Exit

指揮:
Ask 選択してくださいキャンセル可
突撃
防御
かく乱
End

Switch 選択
Case 1
Talk 隊長
よし、総員突撃！
End
Call 突撃
Case 2
Talk 隊長
防御陣形を取れ！
End
Call 防御
Case 3
Talk 隊長
総員散れっ！敵をかく乱する！
End
Call かく乱
EndSw
Exit

指揮不可:
Talk システム
指揮は1ターンに1つしか選べません。
End
Retum

突撃:
ForEach 味方
SetStatus 攻撃力ＵＰ 1
Next

ForEach 味方
SetStatus 移動力ＵＰ 1
Next

ForEach 味方
SetStatus 防御力ＤＯＷＮ 1
Next
Set 指揮判定 1
Return

防御:
ForEach 味方
SetStatus 防御力ＵＰ 1
Next

ForEach 味方
SetStatus 運動性ＤＯＷＮ 1
Next

ForEach 味方
SetStatus 攻撃力ＤＯＷＮ 1
Next
Set 指揮判定 1
Return

かく乱:
ForEach 味方
SetStatus 運動性ＵＰ 1
Next

ForEach 味方
SetStatus 攻撃力ＤＯＷＮ 1
Next

ForEach 味方
SetStatus 防御力ＤＯＷＮ 1
Next

ForEach 敵
SetStatus 撹乱 1
Next
Set 指揮判定 1
Return

引用返信/返信削除キー/

■15810 / inTopicNo.6)

　Re[4]: 全体状態変化

▲▼■

□投稿者/ Mr.tonkati -(2005/01/08(Sat) 07:45:15) [ID:ilM5azDl]

初めまして、おはようございます。Mr.tonkatiです。
特にうまい作り方がわかる訳ではありませんが、気付いたことがありましたので書き込ませていただきます。

サブルーチン"指揮不可"の最後の行の、returnのスペルミス以外は、特に深刻な問題は無いのではないかと思います。
少なくとも、上に挙げられたデータに関しましては。
(なお、マップが無いのは無視しております、ご了承ください。)

では、失礼致しました。

引用返信/返信削除キー/

■15824 / inTopicNo.7)

　Re[4]: 全体状態変化

▲▼■

□投稿者/ ハク -(2005/01/08(Sat) 15:25:05) [ID:gz7VQwOo]

ハクというものです。

> 変更してみたけどだめでした。

Libフォルダ内のInclude.eveで読み込むよう指定したファイル内でも
ユニットコマンド「指揮」を作成していないか確認してください。

------------

ターン全味方:
Set 指揮判定 0
Exit

ユニットコマンド指揮隊長:
If 指揮判定 = 0 Then
　Call 指揮
Else
　Call 指揮不可
EndIf
Exit

指揮:
Ask 選択してくださいキャンセル可
突撃
防御
かく乱
End
Switch 選択
Case 1
　Talk 隊長
　よし、総員突撃！
　End
　Call 突撃
Case 2
　Talk 隊長
　防御陣形を取れ！
　End
　Call 防御
Case 3
　Talk 隊長
　総員散れっ！敵をかく乱する！
　End
　Call かく乱
EndSw
Return

指揮不可:
Talk システム
指揮は1ターンに1つしか選べません。
End
Return

突撃:
ForEach 味方
　SetStatus 攻撃力ＵＰ 1
　SetStatus 移動力ＵＰ 1
　SetStatus 防御力ＤＯＷＮ 1
　Next
Set 指揮判定 1
Return

防御:
ForEach 味方
　SetStatus 防御力ＵＰ 1
　SetStatus 運動性ＤＯＷＮ 1
　SetStatus 攻撃力ＤＯＷＮ 1
Next
Set 指揮判定 1
Return

かく乱:
ForEach 味方
　SetStatus 運動性ＵＰ 1
　SetStatus 攻撃力ＤＯＷＮ 1
　SetStatus 防御力ＤＯＷＮ 1
Next
ForEach 敵
　SetStatus 撹乱 1
Next
Set 指揮判定 1
Return

--------

・"指揮不可"のretumをreturnに
・"指揮"のExitをReturnに
・ForEachをひとまとめに

で正常な動作を確認しています。参考までに。

引用返信/返信削除キー/

■15827 / inTopicNo.8)

　Re[5]: 全体状態変化

▲▼■

□投稿者/ もけ -(2005/01/08(Sat) 21:22:49) [ID:emsUwaTD]

■No15824に返信(ハクさんの記事)
> Libフォルダ内のInclude.eveで読み込むよう指定したファイル内でも
> ユニットコマンド「指揮」を作成していないか確認してください。
そのとおりでした。前に製作したインクルードが残ってました。
指導してくださったTomTomさん、Mr.tonkatiさん、ハクさん本当にありがとうございました。
また何かの際には質問をすることがあると思いますのでよろしくお願いします。

解決済み!

引用返信/返信削除キー/

トピック内ページ移動 / << 0 >>

このトピックに書きこむ

過去ログには書き込み不可

HOME HELP 新規作成新着記事トピック表示検索新着情報過去ログ

- Child Tree -
- Antispam Version -