ＳＲＣ質問掲示板Mk2 [One Topic All View / Re[5]: 複雑な複数パイロットのダイアログデータ / Page: 0]

ＳＲＣ質問掲示板Mk2
(現在過去ログ132 を表示中)

[ 最新記事及び返信フォームをトピックトップへ ]

■22617 / inTopicNo.1)

　複雑な複数パイロットのダイアログデータ

□投稿者/ からげんき -(2012/02/29(Wed) 17:55:31) [ID:a0M7X0gr]

2012/03/01(Thu) 12:23:11 編集(投稿者)

初めまして。からげんきという者です。

現在、３人乗りでかつ形態によってメインパイロットが変わり更にパイロット候補が10数人いて頻繁に乗り換えるというユニットのデータを作っているのですが、パイロットダイアログで全てのバリエーションを再現するとなると膨大なデータ量が必要になってしまうため、うまくコンパクトにまとめる方法を探しています。

最初は

## pilot.txt

パイロット１
パイロット１, -, ユニット, AAAA, 100
特殊能力なし
100, 100, 100, 100, 100, 100, 普通
ＳＰ, 50
pilot.bmp, -.mid
===
パイロット能力付加="パイロット１サブ搭乗=非表示" (!パイロット１)
メッセージクラス=パイロット１サブ (!パイロット１)

#以下２～１０省略

## robot.txt

ロボット１
ロボット１, ユニット, (3), 2
陸, 4, L, 100, 10
特殊能力
変形=変形ロボット２ロボット３
ダイアログ制御
1000, 10, 100, 10
-AAA, -.bmp

ロボット２
ロボット２, ユニット, (3), 2
陸, 4, L, 100, 10
特殊能力
変形=変形ロボット３ロボット１
ダイアログ制御
1000, 10, 100, 10
-AAA, -.bmp

ロボット３
ロボット３, ユニット, (3), 2
陸, 4, L, 100, 10
特殊能力
変形=変形ロボット１ロボット２
ダイアログ制御
1000, 10, 100, 10
-AAA, -.bmp

## alias.txt

ダイアログ制御
メッセージクラス=１＆２サブ (パイロット１サブ搭乗パイロット２サブ搭乗)
メッセージクラス=１＆３サブ (パイロット１サブ搭乗パイロット３サブ搭乗)
メッセージクラス=１＆４サブ (パイロット１サブ搭乗パイロット４サブ搭乗)
メッセージクラス=１＆５サブ (パイロット１サブ搭乗パイロット５サブ搭乗)
##（中略）
メッセージクラス=９＆１０サブ (パイロット９サブ搭乗パイロット１０サブ搭乗)

## pilot_dialog.txt

パイロット１
回避(パイロット２サブ)
パイロット１, -
パイロット２, -
回避(パイロット３サブ)
パイロット１, -
パイロット３, -
回避(２＆３サブ)
パイロット２, -
パイロット３, -

というような形で掛け合いのあるセリフを制御しようとしていたのですが、現状のSRCの仕様ではどうやら２つ以上のメッセージクラスがあると２個目からは機能しなくなってしまうようでうまくいきませんでした。
何か方法がありましたらお教えください。よろしくお願いします。

引用返信/返信削除キー/

■22620 / inTopicNo.2)

　Re[1]: 複雑な複数パイロットのダイアログデータ

▲▼■

□投稿者/ HOLIC -(2012/03/02(Fri) 00:34:27) [ID:p68LwK2R]

こんばんわ。

>パイロット１
>パイロット１, -, ユニット, AAAA, 100
>特殊能力なし
>100, 100, 100, 100, 100, 100, 普通
>ＳＰ, 50
>pilot.bmp, -.mid
>===
>パイロット能力付加="パイロット１サブ搭乗=非表示" (!パイロット１)
>メッセージクラス=パイロット１サブ (!パイロット１)

そもそも()付きユニットの場合、サブパイロット名称は必要技能扱いされません。
なので必要技能(!パイロット１)はパイロット１がメインの時は条件を満たさず、サブの時は認識されませんので実質無意味です。
搭乗パイロット別を対戦相手のメッセージに絡ませるにしても、パイロット１サブ搭乗一つで充分ではないでしょうか。

>メッセージクラス=パイロット１サブ (!パイロット１)
を削除することをお勧めします。

また、
>パイロット１
>回避(パイロット２サブ)
>パイロット１, -
>パイロット２, -
>回避(パイロット３サブ)
>パイロット１, -
>パイロット３, -
>回避(２＆３サブ)
>パイロット２, -
>パイロット３, -
２＆３サブ（つまりパイロット２と３が同乗している）の状態でなら、パイロット２サブ（パイロット２が同乗）とパイロット３サブ（パイロット３が同乗）の搭乗条件をも同時に満たしていると思うので、
>パイロット１
>回避(２＆３サブ)
>パイロット１, -
>パイロット２, -
>回避(２＆３サブ)
>パイロット１, -
>パイロット３, -
>回避(２＆３サブ)
>パイロット２, -
>パイロット３, -
のメッセージクラス=２＆３サブ一つで賄えるのではないでしょうか。

拙文失礼しました。

引用返信/返信削除キー/

■22621 / inTopicNo.3)

　Re[2]: 複雑な複数パイロットのダイアログデータ

▲▼■

□投稿者/ からげんき -(2012/03/02(Fri) 02:24:31) [ID:a0M7X0gr]

2012/03/02(Fri) 03:15:06 編集(投稿者)

HOLICさん、お答え頂きありがとうございます。

その方法なのですが、それですと

パイロット１
回避(２＆３サブ)
パイロット１, -
パイロット２, -
回避(２＆４サブ)
パイロット１, -
パイロット２, -
回避(２＆５サブ)
パイロット１, -
パイロット２, -
##(中略)
回避(２＆１０サブ)
パイロット１, -
パイロット２, -

という風にパイロット１とパイロット２の掛け合い１つだけで１０数パターンの条件指定をつけた同じものを用意せざるを得ず、やはりデータ量としては膨大なものになってしまわないでしょうか。
できればもう少しまとめたものにしたいのですが、他に方法はありませんでしょうか？
お答えして頂いている身でわがままを言ってしまい申し訳ありません…

あと

>そもそも()付きユニットの場合、サブパイロット名称は必要技能扱いされません。
>なので必要技能(!パイロット１)はパイロット１がメインの時は条件を満たさず、サブの時は認識されませんので実質無意味です。

この部分なのですが、一応自分で確かめてみたところ()付きユニットで(!パイロット１)というような必要技能を付けるとパイロット１がサブに回り他のパイロットがメインになった時に効力を発揮できるようなのです。
テレポートやバリアなど目に見える能力で確認した場合パイロット１がメインの場合特殊能力欄に現れず、サブに回った際に特殊能力欄に出てきたので恐らく間違いないと思います。
この必要技能がない場合どの形態においてもダイアログ制御の１＆２サブ、１＆３サブ、２＆３サブの条件を同時に満たしてしまうため付けておりました。

引用返信/返信削除キー/

■22623 / inTopicNo.4)

　Re[1]: 複雑な複数パイロットのダイアログデータ

▲▼■

□投稿者/ HR-16 -(2012/03/03(Sat) 06:55:31) [ID:6bzvvpB2]

HR-16です。初めまして。
パイロット候補が１０数人ですか…。仮に１０人でも、10*9*8/2通りの組み合わせですか？それは整理したいですね。

私も試してみましたが、メッセージクラスは１つしか機能しませんね。
となると、ユニットにつけるメッセージクラスを、戦闘毎に変更するというのはどうでしょうか。

ユニット能力
メッセージクラス=ＡとＢ (ＡＢ)
メッセージクラス=ＡとＣ (ＡＣ)
メッセージクラス=ＢとＣ (ＢＣ)

ダイアログ
パイロットＡ
回避(ＡとＢ)
回避(ＡとＣ)
回避(ＢとＣ)

*攻撃ユニット名全:
Call メッセージクラスの切り替え対象ユニットＩＤ
Exit
*攻撃全ユニット名:
Call メッセージクラスの切り替え相手ユニットＩＤ
Exit

メッセージクラスの切り替え:
ClearSkill PilotID(Args(1)) "ＡＢ"
ClearSkill PilotID(Args(1)) "ＡＣ"
ClearSkill PilotID(Args(1)) "ＢＣ"
Switch Random(3)
Case 1
SetSkill PilotID(Args(1)) "ＡＢ" 1 "非表示"
Case 2
SetSkill PilotID(Args(1)) "ＡＣ" 1 "非表示"
Case 3
SetSkill PilotID(Args(1)) "ＢＣ" 1 "非表示"
EndSw
Return

とりあえず、メインＡサブＢＣだけで書いてみました。これでメッセージクラスの切り替えをすることは可能です。
ただ、これも結構大変ですね。パイロット能力の指定（ＡＢＣ…の組み合わせ）を、変数で上手く指定できると少しは楽になると思いますが。
あと、ClearSkillは攻撃後イベントの方が望ましいでしょうね。

とりあえず案だけ出してみました。それでは、失礼します。

引用返信/返信削除キー/

■22628 / inTopicNo.5)

　Re[2]: 複雑な複数パイロットのダイアログデータ

▲▼■

□投稿者/ からげんき -(2012/03/08(Thu) 17:13:13) [ID:a0M7X0gr]

2012/03/08(Thu) 17:18:28 編集(投稿者)

HR-16さん、返信が遅れてしまい申し訳ありません。お答え頂きありがとうございます。
HR-16さんのデータを参考にし、このような形にしてみました。

## alias.txt

ダイアログ処理
メッセージクラス=ダイアログ処理【パイロット１】 (サブ【パイロット１】)
メッセージクラス=ダイアログ処理【パイロット２】 (サブ【パイロット２】)
メッセージクラス=ダイアログ処理【パイロット３】 (サブ【パイロット３】)
メッセージクラス=ダイアログ処理【１＆２】 (サブ【１＆２】)
メッセージクラス=ダイアログ処理【１＆３】 (サブ【１＆３】)
メッセージクラス=ダイアログ処理【２＆３】 (サブ【２＆３】)

## Include.eve

*攻撃ロボット１全:
*攻撃ロボット２全:
*攻撃ロボット３全:
Call メッセージクラスの切り替え対象ユニットＩＤ
Exit

*攻撃全ロボット１:
*攻撃全ロボット２:
*攻撃全ロボット３:
Call メッセージクラスの切り替え相手ユニットＩＤ
Exit

*攻撃後ロボット１全:
*攻撃後ロボット２全:
*攻撃後ロボット３全:
Call メッセージクラスの消去対象ユニットＩＤ
Exit

*攻撃後全ロボット１:
*攻撃後全ロボット２:
*攻撃後全ロボット３:
Call メッセージクラスの消去相手ユニットＩＤ
Exit

メッセージクラスの切り替え:
Switch Pilot(Args(1),2)
Case パイロット１
Switch Pilot(Args(1),3)
Case パイロット２
Switch Random(3)
Case 1
SetSkill PilotID(Args(1)) "サブ【パイロット１】" 1 "非表示"
Case 2
SetSkill PilotID(Args(1)) "サブ【パイロット２】" 1 "非表示"
Case 3
SetSkill PilotID(Args(1)) "サブ【１＆２】" 1 "非表示"
EndSw
Case パイロット３
Switch Random(3)
Case 1
SetSkill PilotID(Args(1)) "サブ【パイロット１】" 1 "非表示"
Case 2
SetSkill PilotID(Args(1)) "サブ【パイロット３】" 1 "非表示"
Case 3
SetSkill PilotID(Args(1)) "サブ【１＆３】" 1 "非表示"
EndSw
Case Else

EndSw

Case パイロット２
Switch Pilot(Args(1),3)
Case パイロット１
Switch Random(3)
Case 1
SetSkill PilotID(Args(1)) "サブ【パイロット２】" 1 "非表示"
Case 2
SetSkill PilotID(Args(1)) "サブ【パイロット１】" 1 "非表示"
Case 3
SetSkill PilotID(Args(1)) "サブ【１＆２】" 1 "非表示"
EndSw
Case パイロット３
Switch Random(3)
Case 1
SetSkill PilotID(Args(1)) "サブ【パイロット２】" 1 "非表示"
Case 2
SetSkill PilotID(Args(1)) "サブ【パイロット３】" 1 "非表示"
Case 3
SetSkill PilotID(Args(1)) "サブ【２＆３】" 1 "非表示"
EndSw

Case パイロット３
Switch Pilot(Args(1),3)
Case パイロット１
Switch Random(3)
Case 1
SetSkill PilotID(Args(1)) "サブ【パイロット３】" 1 "非表示"
Case 2
SetSkill PilotID(Args(1)) "サブ【パイロット１】" 1 "非表示"
Case 3
SetSkill PilotID(Args(1)) "サブ【１＆３】" 1 "非表示"
EndSw
Case パイロット２
Switch Random(3)
Case 1
SetSkill PilotID(Args(1)) "サブ【パイロット３】" 1 "非表示"
Case 2
SetSkill PilotID(Args(1)) "サブ【パイロット２】" 1 "非表示"
Case 3
SetSkill PilotID(Args(1)) "サブ【２＆３】" 1 "非表示"
EndSw
Case Else

EndSw

Case Else

Endsw
Return

メッセージクラスの消去:
ClearSkill PilotID(Args(1)) "サブ【パイロット１】"
ClearSkill PilotID(Args(1)) "サブ【パイロット２】"
ClearSkill PilotID(Args(1)) "サブ【パイロット３】"
ClearSkill PilotID(Args(1)) "サブ【１＆２】"
ClearSkill PilotID(Args(1)) "サブ【１＆３】"
ClearSkill PilotID(Args(1)) "サブ【２＆３】"
Return

###

一応動作は確認できたのですがミスや簡略化、改良可能な点があればご指摘ください。
よろしくお願いします。

引用返信/返信削除キー/

■22632 / inTopicNo.6)

　Re[3]: 複雑な複数パイロットのダイアログデータ

▲▼■

□投稿者/ HR-16 -(2012/03/10(Sat) 22:12:20) [ID:6HUSztTb]

こんばんは。HR-16です。
まずは、動作したようなので良かったです。
上に書かれたものだと、サブパイ１がパイロット２の場合の所で「EndSw」が足りない気がするのですが、動作したのであれば大丈夫でしょう。

その他に、思ったことを２点ほど。

１つは、攻撃後イベントについて。
攻撃後イベントは戦闘でどちらかのユニットが破壊されると発生しないので、破壊イベントでも同様の設定が必要かと思います。
*破壊ユニット名:
Call メッセージクラスの消去対象ユニットＩＤ
Exit
*破壊全:
If (Unit(相手ユニットＩＤ) = ユニット名) Then
Call メッセージクラスの消去相手ユニットＩＤ
EndIf
Exit

もう１つは、「メッセージクラスの切り替え」の中での場合分けの仕方です。
サブパイ１人との掛け合いなら楽に設定できるので、ランダム判定を先にしたほうがスッキリすると思います。
Switch Random(3)
# サブパイ１と掛け合い
Case 1
Switch Pilot(Args(1),2)
Case パイロット１
SetSkill PilotID(Args(1)) "サブ【パイロット１】" 1 "非表示"
Case パイロット２
SetSkill PilotID(Args(1)) "サブ【パイロット２】" 1 "非表示"
Case パイロット３
SetSkill PilotID(Args(1)) "サブ【パイロット３】" 1 "非表示"
Case Else
EndSw
# サブパイ２と掛け合い
Case 2
Switch Pilot(Args(1),3)
#Case1のコピペで。
EndSw
# サブパイ同士
Case 3
Switch Pilot(Args(1),2)
Case パイロット１
Switch Pilot(Args(1),3)
Case パイロット２
SetSkill PilotID(Args(1)) "サブ【１＆２】" 1 "非表示"
Case パイロット３
SetSkill PilotID(Args(1)) "サブ【１＆３】" 1 "非表示"
Case Else
EndSw
Case パイロット２
Case パイロット３
Case Else
EndSw
EndSw

それでは、失礼します。

引用返信/返信削除キー/

■22633 / inTopicNo.7)

　Re[4]: 複雑な複数パイロットのダイアログデータ

▲▼■

□投稿者/ からげんき -(2012/03/11(Sun) 02:28:20) [ID:a0M7X0gr]

2012/03/11(Sun) 03:10:17 編集(投稿者)

HR-16さん、度々ありがとうございます。

>上に書かれたものだと、サブパイ１がパイロット２の場合の所で「EndSw」が足りない気がするのですが、動作したのであれば大丈夫でしょう。

確かめてみたら確かに抜けていますね、Include.eveの方は正常だったのでどうもコピペした後指定名称を仮のものに変える際にうっかり消してしまったようです。
お騒がせしました。

前回の書式でInclude.eveをパイロット全パターン分作っていたのですが、HR-16さんのアドバイスをもとに改良したところ容量が半分以下になりました。
よくよく考えてみればそれぞれのパターンにさらに３パターンを追加するよりこちらの方が断然文量を抑えられますよね、せっかくアドバイスをもらっているというのに全然使いこなせておらず申し訳ありません…

改めて、それとは別に全パターン分のInclude.eveを作って見たところ「メッセージクラスの消去」の部分でちょっとした問題が発生しました。
私のPCの性能のせいなのかもしれませんが、どうもClearSkillの量が多すぎるようで(数えてみたところ135個ほど)メッセージクラスの消去を指定されたユニットが戦うごとに10秒間ほど処理のためにSRCが操作を受け付けなくなってしまいます。

色々試しては見ているのですが、やはりこちらもメッセージクラスの切り替えと同様にSwitchでClearSkillをパターン分けして処理を軽くするくらいしか解決方法はないのでしょうか。
何度もすみませんが、よろしくお願いします。

引用返信/返信削除キー/

■22634 / inTopicNo.8)

　Re[5]: 複雑な複数パイロットのダイアログデータ

▲▼■

□投稿者/ HR-16 -(2012/03/11(Sun) 13:17:40) [ID:6HUSztTb]

HR-16です。
ClearSkillを100回で試してみました。私のＰＣ環境では、これで１秒程止まる感じでした。
135回で10秒は、ＰＣ能力による部分も大きい気がしますが、何にせよ対処は必要なレベルだと私も思います。

場合分けをするなら前と同じなので、変数でやる方法を。
先に説明をすると、サブパイが１と２の場合に下のコマンドを実行するものです。
ClearSkill PilotID(Args(1)) "サブ【パイロット１】"
ClearSkill PilotID(Args(1)) "サブ【パイロット２】"
ClearSkill PilotID(Args(1)) "サブ【１＆２】"
ClearSkill PilotID(Args(1)) "サブ【２＆１】"

###
メッセージクラスの消去:
Local sub1 sub2
Switch Pilot(Args(1),2)
Case パイロット１
Set sub1 "１"
Case パイロット２
Set sub1 "２"
EndSw
Switch Pilot(Args(1),3)
Case パイロット１
Set sub2 "１"
Case パイロット２
Set sub2 "２"
EndSw
ClearSkill PilotID(Args(1)) ("サブ【パイロット" & sub1 & "】")
ClearSkill PilotID(Args(1)) ("サブ【パイロット" & sub2 & "】")
ClearSkill PilotID(Args(1)) ("サブ【" & sub1 & "＆" & sub2 & "】")
ClearSkill PilotID(Args(1)) ("サブ【" & sub2 & "＆" & sub1 & "】")
Return
###

なお、変数を使っての指定は、SetSkillの場合も可能です。（@メッセージクラスの切り替え）
ただ、「１＆２」と「２＆１」など並び順を気にしないといけない…
…と思っていましたが、考え直してみると両方セットしていても問題なさそうですね。メッセージクラスは結局１つしかセットされませんし、上のやり方で両方クリアスキルすれば良いですし。
なので、メッセージクラスの切り替えの方もこのやり方にしてみても良いと思います（今更で申し訳ないですが）。

引用返信/返信削除キー/

■22635 / inTopicNo.9)

　Re[5]: 複雑な複数パイロットのダイアログデータ

▲▼■

□投稿者/ 中箱 -(2012/03/11(Sun) 15:10:14) [ID:XAPi9INn]

＞私のPCの性能のせいなのかもしれませんが、どうもClearSkillの量が多すぎるようで(数えてみたところ135個ほど)
＞メッセージクラスの消去を指定されたユニットが戦うごとに10秒間ほど処理のためにSRCが操作を受け付けなくなってしまいます。
＞
＞色々試しては見ているのですが、やはりこちらもメッセージクラスの切り替えと同様に
＞SwitchでClearSkillをパターン分けして処理を軽くするくらいしか解決方法はないのでしょうか。
＞何度もすみませんが、よろしくお願いします。

ClearSkillは比較的処理の重いコマンドですから、大量のClearSkillコマンドを実行する場合は、
直前にSkill関数かInfo関数でその特殊能力を持っているかどうかをチェックして特殊能力を持っている場合のみClearSkillコマンドを実行するようにすることで、
チェックせずにClearSkillコマンドだけを並べた場合に比べて目に見えて軽くなります。（私が軽く試した限りでは10倍ぐらい）

軽さを考えるのであれば場合分けした方が軽くなるとは思いますが

引用返信/返信削除キー/

■22636 / inTopicNo.10)

　Re[5]: 複雑な複数パイロットのダイアログデータ

▲▼■

□投稿者/ からげんき -(2012/03/11(Sun) 23:54:26) [ID:a0M7X0gr]

2012/04/04(Wed) 00:13:42 編集(投稿者)
2012/03/11(Sun) 23:58:50 編集(投稿者)

HR-16さん、中箱さん、お答え頂きありがとうございます。
丁寧な解説、毎回痛み入ります。
変数と関数ですか…シナリオやデータを作り出したのは最近なもので良く分かっていなかったのですが、なるほどこういう使い方をするものなのですね。
お二人のアドバイスを参考にインクルードを少し改良してみました。
メッセージクラスの消去はほぼHR-16さんのデータそのままなので割愛しますが、それ以外の部分でおかしな点があればご指摘下さい。
それでは、よろしくお願いします

### 呼び出し ########################################################

*攻撃全全:
#攻撃したのがそのユニットクラスを持つなら
If (Info(対象ユニットＩＤ,ユニットクラス) = 専用ユニットクラス) Then
Call メッセージクラスの切り替え対象ユニットＩＤ
EndIf
#攻撃されたのがそのユニットクラスを持つなら
If (Info(相手ユニットＩＤ,ユニットクラス) = 専用ユニットクラス) Then
Call メッセージクラスの切り替え相手ユニットＩＤ
EndIf
Exit

*攻撃後全全:
If (Info(対象ユニットＩＤ,ユニットクラス) = 専用ユニットクラス) Then
Call メッセージクラスの消去対象ユニットＩＤ
EndIf
If (Info(相手ユニットＩＤ,ユニットクラス) = 専用ユニットクラス) Then
Call メッセージクラスの消去相手ユニットＩＤ
EndIf
Exit

*破壊全:
#破壊されたのがそのユニットクラスを持つなら
If (Info(対象ユニットＩＤ,ユニットクラス) = 専用ユニットクラス) Then
Call メッセージクラスの消去対象ユニットＩＤ
EndIf
#相手を破壊したのがそのユニットクラスを持つなら
If (Info(相手ユニットＩＤ,ユニットクラス) = 専用ユニットクラス) Then
Call メッセージクラスの消去相手ユニットＩＤ
EndIf
Exit

### メッセージクラスの切り替え ###############################################

メッセージクラスの切り替え:
Local sub1 sub2
#サブパイ１の指定
Switch Pilot(Args(1),2)
Case パイロット１
Set sub1 "１"
Case パイロット
Set sub1 "２"
Case パイロット
Set sub1 "３"
Case Else
Set sub1 "なし"
EndSw
#サブパイ２の指定
Switch Pilot(Args(1),3)
Case パイロット１
Set sub2 "１"
Case パイロット２
Set sub2 "２"
Case パイロット３
Set sub2 "３"
Case Else
Set sub2 "なし"
EndSw
## 掛け合いスキルセット
Switch Random(3)
## サブパイ１と掛け合い
Case 1
SetSkill PilotID(Args(1)) ("サブ【パイロット" & sub1 & "】") 1 "非表示"
## サブパイ２と掛け合い
Case 2
SetSkill PilotID(Args(1)) ("サブ【パイロット" & sub2 & "】") 1 "非表示"
## ３人での掛け合い
Case 3
SetSkill PilotID(Args(1)) ("サブ【" & sub1 & "＆" & sub2 & "】") 1 "非表示"
SetSkill PilotID(Args(1)) ("サブ【" & sub2 & "＆" & sub1 & "】") 1 "非表示"
EndSw
Return

##### 追記

ご報告が遅れてしまい申し訳有りません。
また多少改変いたしましたが、このインクルードでの動作が問題なくできているのでここで解決済みにしたいと思います。
皆さんのおかげでなんとかここまで形にすることができました。
お答えして頂いた皆様、誠にありがとうございました。

解決済み!

引用返信/返信削除キー/

トピック内ページ移動 / << 0 >>

このトピックに書きこむ

過去ログには書き込み不可

HOME HELP 新規作成新着記事トピック表示検索新着情報過去ログ

- Child Tree -
- Antispam Version -